forked from Shinonome/alt-illogical-impulse
Celes Renata
ac6d3adeb9
BREAKING CHANGE: Remove external dots-hyprland dependency - Imported all essential configs from dots-hyprland/installer-replication - Added complete configs/ directory with: - hypr/ - Hyprland configuration - quickshell/ - Quickshell widgets and config - applications/ - Application configurations - scripts/ - Utility scripts - matugen/ - Material You theming - Updated flake.nix to use local ./configs instead of external repo - Simplified update-flake script (removed external repo management) - Updated README to reflect self-contained architecture - All builds pass with local configurations Benefits: - No external repository dependencies - Faster builds (no network dependencies) - Version controlled configs in single repo - Easier maintenance and development - Complete installer replication in one place
73 lines
1.9 KiB
QML
73 lines
1.9 KiB
QML
import qs.modules.common
|
|
import qs.modules.common.functions
|
|
import QtQuick
|
|
import QtQuick.Layouts
|
|
import Quickshell
|
|
import Quickshell.Services.SystemTray
|
|
import Quickshell.Widgets
|
|
import Qt5Compat.GraphicalEffects
|
|
|
|
MouseArea {
|
|
id: root
|
|
|
|
required property var bar
|
|
required property SystemTrayItem item
|
|
property bool targetMenuOpen: false
|
|
property int trayItemWidth: Appearance.font.pixelSize.larger
|
|
|
|
acceptedButtons: Qt.LeftButton | Qt.RightButton
|
|
Layout.fillHeight: true
|
|
implicitWidth: trayItemWidth
|
|
onClicked: (event) => {
|
|
switch (event.button) {
|
|
case Qt.LeftButton:
|
|
item.activate();
|
|
break;
|
|
case Qt.RightButton:
|
|
if (item.hasMenu) menu.open();
|
|
break;
|
|
}
|
|
event.accepted = true;
|
|
}
|
|
|
|
QsMenuAnchor {
|
|
id: menu
|
|
|
|
menu: root.item.menu
|
|
anchor.window: bar
|
|
anchor.rect.x: root.x + bar.width
|
|
anchor.rect.y: root.y
|
|
anchor.rect.height: root.height
|
|
anchor.edges: Edges.Bottom
|
|
}
|
|
|
|
IconImage {
|
|
id: trayIcon
|
|
visible: !Config.options.bar.tray.monochromeIcons
|
|
source: root.item.icon
|
|
anchors.centerIn: parent
|
|
width: parent.width
|
|
height: parent.height
|
|
}
|
|
|
|
Loader {
|
|
active: Config.options.bar.tray.monochromeIcons
|
|
anchors.fill: trayIcon
|
|
sourceComponent: Item {
|
|
Desaturate {
|
|
id: desaturatedIcon
|
|
visible: false // There's already color overlay
|
|
anchors.fill: parent
|
|
source: trayIcon
|
|
desaturation: 0.8 // 1.0 means fully grayscale
|
|
}
|
|
ColorOverlay {
|
|
anchors.fill: desaturatedIcon
|
|
source: desaturatedIcon
|
|
color: ColorUtils.transparentize(Appearance.colors.colOnLayer0, 0.9)
|
|
}
|
|
}
|
|
}
|
|
|
|
}
|