forked from Shinonome/alt-illogical-impulse
Celes Renata
ac6d3adeb9
BREAKING CHANGE: Remove external dots-hyprland dependency - Imported all essential configs from dots-hyprland/installer-replication - Added complete configs/ directory with: - hypr/ - Hyprland configuration - quickshell/ - Quickshell widgets and config - applications/ - Application configurations - scripts/ - Utility scripts - matugen/ - Material You theming - Updated flake.nix to use local ./configs instead of external repo - Simplified update-flake script (removed external repo management) - Updated README to reflect self-contained architecture - All builds pass with local configurations Benefits: - No external repository dependencies - Faster builds (no network dependencies) - Version controlled configs in single repo - Easier maintenance and development - Complete installer replication in one place
63 lines
2.1 KiB
QML
63 lines
2.1 KiB
QML
pragma Singleton
|
|
pragma ComponentBehavior: Bound
|
|
|
|
import qs.modules.common
|
|
import QtQuick
|
|
import Quickshell
|
|
import Quickshell.Io
|
|
|
|
/**
|
|
* Simple polled resource usage service with RAM, Swap, and CPU usage.
|
|
*/
|
|
Singleton {
|
|
property double memoryTotal: 1
|
|
property double memoryFree: 1
|
|
property double memoryUsed: memoryTotal - memoryFree
|
|
property double memoryUsedPercentage: memoryUsed / memoryTotal
|
|
property double swapTotal: 1
|
|
property double swapFree: 1
|
|
property double swapUsed: swapTotal - swapFree
|
|
property double swapUsedPercentage: swapTotal > 0 ? (swapUsed / swapTotal) : 0
|
|
property double cpuUsage: 0
|
|
property var previousCpuStats
|
|
|
|
Timer {
|
|
interval: 1
|
|
running: true
|
|
repeat: true
|
|
onTriggered: {
|
|
// Reload files
|
|
fileMeminfo.reload()
|
|
fileStat.reload()
|
|
|
|
// Parse memory and swap usage
|
|
const textMeminfo = fileMeminfo.text()
|
|
memoryTotal = Number(textMeminfo.match(/MemTotal: *(\d+)/)?.[1] ?? 1)
|
|
memoryFree = Number(textMeminfo.match(/MemAvailable: *(\d+)/)?.[1] ?? 0)
|
|
swapTotal = Number(textMeminfo.match(/SwapTotal: *(\d+)/)?.[1] ?? 1)
|
|
swapFree = Number(textMeminfo.match(/SwapFree: *(\d+)/)?.[1] ?? 0)
|
|
|
|
// Parse CPU usage
|
|
const textStat = fileStat.text()
|
|
const cpuLine = textStat.match(/^cpu\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)/)
|
|
if (cpuLine) {
|
|
const stats = cpuLine.slice(1).map(Number)
|
|
const total = stats.reduce((a, b) => a + b, 0)
|
|
const idle = stats[3]
|
|
|
|
if (previousCpuStats) {
|
|
const totalDiff = total - previousCpuStats.total
|
|
const idleDiff = idle - previousCpuStats.idle
|
|
cpuUsage = totalDiff > 0 ? (1 - idleDiff / totalDiff) : 0
|
|
}
|
|
|
|
previousCpuStats = { total, idle }
|
|
}
|
|
interval = Config.options?.resources?.updateInterval ?? 3000
|
|
}
|
|
}
|
|
|
|
FileView { id: fileMeminfo; path: "/proc/meminfo" }
|
|
FileView { id: fileStat; path: "/proc/stat" }
|
|
}
|