forked from Shinonome/alt-illogical-impulse
Celes Renata
ac6d3adeb9
BREAKING CHANGE: Remove external dots-hyprland dependency - Imported all essential configs from dots-hyprland/installer-replication - Added complete configs/ directory with: - hypr/ - Hyprland configuration - quickshell/ - Quickshell widgets and config - applications/ - Application configurations - scripts/ - Utility scripts - matugen/ - Material You theming - Updated flake.nix to use local ./configs instead of external repo - Simplified update-flake script (removed external repo management) - Updated README to reflect self-contained architecture - All builds pass with local configurations Benefits: - No external repository dependencies - Faster builds (no network dependencies) - Version controlled configs in single repo - Easier maintenance and development - Complete installer replication in one place
67 lines
2.3 KiB
QML
67 lines
2.3 KiB
QML
import qs.modules.common
|
|
import qs.modules.common.widgets
|
|
import QtQuick
|
|
import QtQuick.Controls
|
|
import QtQuick.Layouts
|
|
import Quickshell
|
|
import Quickshell.Wayland
|
|
import Quickshell.Hyprland
|
|
|
|
Scope {
|
|
id: screenCorners
|
|
readonly property Toplevel activeWindow: ToplevelManager.activeToplevel
|
|
|
|
component CornerPanelWindow: PanelWindow {
|
|
id: cornerPanelWindow
|
|
visible: (Config.options.appearance.fakeScreenRounding === 1 || (Config.options.appearance.fakeScreenRounding === 2 && !activeWindow?.fullscreen))
|
|
property var corner
|
|
|
|
exclusionMode: ExclusionMode.Ignore
|
|
mask: Region {
|
|
item: null
|
|
}
|
|
WlrLayershell.namespace: "quickshell:screenCorners"
|
|
WlrLayershell.layer: WlrLayer.Overlay
|
|
color: "transparent"
|
|
|
|
anchors {
|
|
top: cornerPanelWindow.corner === RoundCorner.CornerEnum.TopLeft || cornerPanelWindow.corner === RoundCorner.CornerEnum.TopRight
|
|
left: cornerPanelWindow.corner === RoundCorner.CornerEnum.TopLeft || cornerPanelWindow.corner === RoundCorner.CornerEnum.BottomLeft
|
|
bottom: cornerPanelWindow.corner === RoundCorner.CornerEnum.BottomLeft || cornerPanelWindow.corner === RoundCorner.CornerEnum.BottomRight
|
|
right: cornerPanelWindow.corner === RoundCorner.CornerEnum.TopRight || cornerPanelWindow.corner === RoundCorner.CornerEnum.BottomRight
|
|
}
|
|
|
|
implicitWidth: cornerWidget.implicitWidth
|
|
implicitHeight: cornerWidget.implicitHeight
|
|
RoundCorner {
|
|
id: cornerWidget
|
|
size: Appearance.rounding.screenRounding
|
|
corner: cornerPanelWindow.corner
|
|
}
|
|
}
|
|
|
|
Variants {
|
|
model: Quickshell.screens
|
|
|
|
Scope {
|
|
required property var modelData
|
|
CornerPanelWindow {
|
|
screen: modelData
|
|
corner: RoundCorner.CornerEnum.TopLeft
|
|
}
|
|
CornerPanelWindow {
|
|
screen: modelData
|
|
corner: RoundCorner.CornerEnum.TopRight
|
|
}
|
|
CornerPanelWindow {
|
|
screen: modelData
|
|
corner: RoundCorner.CornerEnum.BottomLeft
|
|
}
|
|
CornerPanelWindow {
|
|
screen: modelData
|
|
corner: RoundCorner.CornerEnum.BottomRight
|
|
}
|
|
}
|
|
}
|
|
}
|