Switch to AGS v1.9.0 (#1092)

and switch bin name for [preparing migrating to agsv2](https://github.com/Aylur/ags/issues/618#issuecomment-2476866842)
2025-02-10 09:04:28 +08:00
parent 44e29ab974
commit 285f817728
10 changed files with 94 additions and 33 deletions
@@ -0,0 +1,2 @@
+/ags/
+/libgnome-volume-control/
@@ -0,0 +1,56 @@
+# Borrowed from https://github.com/kotontrion/PKGBUILDS/blob/main/agsv1/PKGBUILD
+#
+# Maintainer: kotontrion <kotontrion@tutanota.de>
+
+# This package is only intended to be used while migrating from ags v1.8.2 to ags v2.0.0.
+# Many ags configs are quite big and it takes a while to migrate, therefore I made this package
+# to install ags v1.8.2 as "agsv1", so both versions can be installed at the same time, making it
+# possible to migrate bit by bit while still having a working v1 config around. 
+#
+# First update the aylurs-gtk-shell package to v2, then install this one.
+#
+# This package won't receive any updates anymore, so as soon as you migrated, uninstall this one.
+
+pkgname=illogical-impulse-agsv1
+_pkgname=ags
+pkgver=1.9.0
+pkgrel=1
+pkgdesc="Aylurs's Gtk Shell (AGS), An eww inspired gtk widget system."
+arch=('x86_64')
+url="https://github.com/Aylur/ags"
+license=('GPL-3.0-only')
+makedepends=('git' 'gobject-introspection' 'meson' 'glib2-devel' 'npm' 'typescript')
+depends=('gvfs' 'gjs' 'glib2' 'glib2-devel' 'glibc' 'gtk3' 'gtk-layer-shell' 'libpulse' 'pam' 'gnome-bluetooth-3.0' 'gammastep')
+optdepends=('gnome-bluetooth-3.0: required for bluetooth service'
+            'greetd: required for greetd service'
+            'libdbusmenu-gtk3: required for systemtray service'
+            'libsoup3: required for the Utils.fetch feature'
+            'libnotify: required for sending notifications'
+            'networkmanager: required for network service'
+            'power-profiles-daemon: required for powerprofiles service'
+            'upower: required for battery service')
+conflicts=('illogical-impulse-ags')
+backup=('etc/pam.d/ags')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/Aylur/ags/archive/refs/tags/v${pkgver}.tar.gz"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control")
+sha256sums=('962f99dcf202eef30e978d1daedc7cdf213e07a3b52413c1fb7b54abc7bd08e6'
+            SKIP)
+
+prepare() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  mv -T "$srcdir"/libgnome-volume-control subprojects/gvc
+}
+
+build() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  npm install
+  arch-meson build --libdir "lib/$_pkgname" -Dbuild_types=true
+  meson compile -C build
+}
+
+package() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  meson install -C build --destdir "$pkgdir"
+  rm ${pkgdir}/usr/bin/ags
+  ln -sf /usr/share/com.github.Aylur.ags/com.github.Aylur.ags ${pkgdir}/usr/bin/agsv1
+}