waffles: action center: volume menu

2025-11-19 23:39:18 +01:00
parent bca177eed2
commit 5c8d824749
42 changed files with 680 additions and 129 deletions
@@ -0,0 +1,37 @@
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import qs
+import qs.services
+import qs.modules.common
+import qs.modules.common.functions
+import qs.modules.waffle.looks
+import qs.modules.waffle.actionCenter
+
+BodyRectangle {
+    id: root
+    implicitHeight: contentLayout.implicitHeight
+
+    ColumnLayout {
+        id: contentLayout
+        anchors.fill: parent
+        spacing: 0
+
+        MainPageBodyToggles {
+            id: togglesContainer
+            Layout.fillWidth: true
+        }
+
+        Rectangle {
+            implicitHeight: 1
+            Layout.fillWidth: true
+            color: Looks.colors.bg1Border
+        }
+
+        MainPageBodySliders {
+            Layout.margins: 12
+            Layout.topMargin: 18
+            Layout.bottomMargin: 14
+        }
+    }
+}
@@ -0,0 +1,90 @@
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import qs
+import qs.services
+import qs.modules.common
+import qs.modules.common.functions
+import qs.modules.waffle.looks
+import qs.modules.waffle.actionCenter
+import qs.modules.waffle.actionCenter.volumeControl
+
+ColumnLayout {
+    id: root
+    property var screen: root.QsWindow.window?.screen
+    property var brightnessMonitor: Brightness.getMonitorForScreen(screen)
+    spacing: 12
+
+    RowLayout {
+        spacing: 4
+
+        WPanelIconButton {
+            color: colBackground
+            property real animationValue: root.brightnessMonitor?.brightness ?? 0
+            rotation: animationValue * 180
+            scale: 0.8 + animationValue * 0.2
+            iconName: "weather-sunny"
+
+            Behavior on animationValue {
+                animation: Looks.transition.longMovement.createObject(this)
+            }
+        }
+        
+        WSlider {
+            Layout.fillWidth: true
+            value: root.brightnessMonitor?.brightness ?? 0
+            onMoved: {
+                root.brightnessMonitor?.setBrightness(value)
+            }
+        }
+
+        WPanelIconButton {
+            opacity: 0
+        }
+    }
+    
+    RowLayout {
+        spacing: 4
+
+        WPanelIconButton {
+            iconName: WIcons.volumeIcon
+            onClicked: Audio.toggleMute();
+        }
+        
+        WSlider {
+            Layout.fillWidth: true
+            value: Audio.sink.audio.volume
+            onMoved: {
+                Audio.sink.audio.volume = value;
+            }
+        }
+
+        WPanelIconButton {
+            Component {
+                id: volumeControlComp
+                VolumeControl {}
+            }
+            onClicked: {
+                ActionCenterContext.push(volumeControlComp)
+            }
+            contentItem: Item {
+                anchors.centerIn: parent
+                Row {
+                    anchors.centerIn: parent
+                    spacing: -1
+                    FluentIcon {
+                        anchors.verticalCenter: parent.verticalCenter
+                        implicitSize: 18
+                        icon: "options"
+                    }
+                    FluentIcon {
+                        anchors.verticalCenter: parent.verticalCenter
+                        implicitSize: 12
+                        icon: "chevron-right"
+                    }
+                }
+            }
+        }
+    }
+
+}
@@ -0,0 +1,139 @@
+pragma ComponentBehavior: Bound
+import Qt.labs.synchronizer
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Controls
+import Quickshell
+import qs
+import qs.services
+import qs.modules.common
+import qs.modules.common.widgets
+import qs.modules.common.models.quickToggles
+import qs.modules.common.functions
+import qs.modules.waffle.looks
+import qs.modules.waffle.actionCenter.toggles
+
+Item {
+    id: root
+
+    property int columns: 3
+    property int rows: 2
+    property int currentPage: 0
+    readonly property int itemsPerPage: columns * rows
+    readonly property int pages: Math.ceil(toggles.length / itemsPerPage)
+    property list<string> toggles: Config.options.waffles.actionCenter.toggles
+
+    property real padding: 22
+    property real reducedBottomPadding: 12
+    implicitHeight: swipeView.implicitHeight + (padding - swipeView.padding) * 2 - reducedBottomPadding
+
+    function togglesInPage(index) {
+        var start = index * root.itemsPerPage;
+        var end = start + root.itemsPerPage;
+        return root.toggles.slice(start, end);
+    }
+
+    function decreasePage() {
+        if (root.currentPage > 0) {
+            root.currentPage -= 1;
+        }
+    }
+
+    function increasePage() {
+        if (root.currentPage < (root.pages - 1)) {
+            root.currentPage += 1;
+        }
+    }
+
+    clip: true
+    SwipeView {
+        id: swipeView
+        anchors {
+            fill: parent
+            topMargin: root.padding - swipeView.padding
+            bottomMargin: root.padding - swipeView.padding - root.reducedBottomPadding
+        }
+        padding: 4
+        leftPadding: root.padding
+        rightPadding: root.padding
+        spacing: padding
+
+        orientation: Qt.Vertical
+        clip: true
+        Synchronizer on currentIndex {
+            property alias source: root.currentPage
+        }
+
+        Repeater {
+            model: root.pages
+            delegate: GridLayout {
+                id: grid
+                required property int index
+                // width: SwipeView.view.width - root.padding * 2
+                // height: SwipeView.view.height - root.padding * 2
+
+                columns: root.columns
+                rows: root.rows
+                rowSpacing: 12
+                columnSpacing: 12
+
+                Repeater {
+                    model: ScriptModel {
+                        values: root.togglesInPage(grid.index)
+                    }
+                    delegate: ActionCenterTogglesDelegateChooser {}
+                }
+            }
+        }
+    }
+
+    Column {
+        anchors.verticalCenter: parent.verticalCenter
+        anchors.right: parent.right
+        anchors.rightMargin: 6
+        spacing: 6
+
+        FluentIcon {
+            anchors.horizontalCenter: parent.horizontalCenter
+            implicitSize: 12
+            icon: "caret-up"
+            color: Looks.colors.controlBg
+            filled: true
+            opacity: root.currentPage > 0 ? 1 : 0
+        }
+
+        Repeater {
+            model: root.pages
+            delegate: Item {
+                required property int index
+                anchors.horizontalCenter: parent.horizontalCenter
+                implicitWidth: 6
+                implicitHeight: 6
+
+                Circle {
+                    anchors.centerIn: parent
+                    diameter: index === root.currentPage ? 6 : 4
+                    color: Looks.colors.controlBg
+                }
+            }
+        }
+
+        FluentIcon {
+            anchors.horizontalCenter: parent.horizontalCenter
+            implicitSize: 12
+            icon: "caret-down"
+            color: Looks.colors.controlBg
+            filled: true
+            opacity: root.currentPage < (root.pages - 1) ? 1 : 0
+        }
+    }
+
+    FocusedScrollMouseArea {
+        z: 999
+        anchors.fill: parent
+        acceptedButtons: Qt.NoButton
+        hoverEnabled: false
+        onScrollUp: decreasePage();
+        onScrollDown: increasePage();
+    }
+}
@@ -0,0 +1,49 @@
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import qs
+import qs.services
+import qs.modules.common
+import qs.modules.common.functions
+import qs.modules.waffle.looks
+import qs.modules.waffle.actionCenter
+
+FooterRectangle {
+
+    // Battery button
+    WPanelFooterButton {
+        visible: Battery.available
+        anchors.verticalCenter: parent.verticalCenter
+        anchors.left: parent.left
+        anchors.leftMargin: 12
+
+        contentItem: Row {
+            spacing: 4
+
+            FluentIcon {
+                anchors.verticalCenter: parent.verticalCenter
+                icon: WIcons.batteryIcon
+            }
+            WText {
+                anchors.verticalCenter: parent.verticalCenter
+                text: `${Math.round(Battery.percentage * 100) || 0}%`
+            }
+        }
+    }
+
+    // Settings button
+    WPanelFooterButton {
+        anchors.verticalCenter: parent.verticalCenter
+        anchors.right: parent.right
+        anchors.rightMargin: 12
+
+        onClicked: {
+            GlobalStates.sidebarLeftOpen = false;
+            Quickshell.execDetached(["qs", "-p", Quickshell.shellPath("settings.qml")]);
+        }
+
+        contentItem: FluentIcon {
+            icon: "settings"
+        }
+    }
+}