Rearrange for tidier structure (#2212)

2025-10-16 07:19:55 +08:00
parent 13065d7e5a
commit 8b493e091d
529 changed files with 165 additions and 138 deletions
@@ -0,0 +1,110 @@
+import qs.services
+import qs.modules.common
+import qs.modules.common.widgets
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import Qt5Compat.GraphicalEffects
+
+Item {
+    id: root
+    required property var scopeRoot
+    anchors.fill: parent
+    property bool aiChatEnabled: Config.options.policies.ai !== 0
+    property bool translatorEnabled: Config.options.sidebar.translator.enable
+    property bool animeEnabled: Config.options.policies.weeb !== 0
+    property bool animeCloset: Config.options.policies.weeb === 2
+    property var tabButtonList: [
+        ...(root.aiChatEnabled ? [{"icon": "neurology", "name": Translation.tr("Intelligence")}] : []),
+        ...(root.translatorEnabled ? [{"icon": "translate", "name": Translation.tr("Translator")}] : []),
+        ...((root.animeEnabled && !root.animeCloset) ? [{"icon": "bookmark_heart", "name": Translation.tr("Anime")}] : [])
+    ]
+    property int selectedTab: 0
+    property int tabCount: swipeView.count
+
+    function focusActiveItem() {
+        swipeView.currentItem.forceActiveFocus()
+    }
+
+    Keys.onPressed: (event) => {
+        if (event.modifiers === Qt.ControlModifier) {
+            if (event.key === Qt.Key_PageDown) {
+                root.selectedTab = Math.min(root.selectedTab + 1, root.tabCount - 1)
+                event.accepted = true;
+            } 
+            else if (event.key === Qt.Key_PageUp) {
+                root.selectedTab = Math.max(root.selectedTab - 1, 0)
+                event.accepted = true;
+            }
+            else if (event.key === Qt.Key_Tab) {
+                root.selectedTab = (root.selectedTab + 1) % root.tabCount;
+                event.accepted = true;
+            }
+            else if (event.key === Qt.Key_Backtab) {
+                root.selectedTab = (root.selectedTab - 1 + root.tabCount) % root.tabCount;
+                event.accepted = true;
+            }
+        }
+    }
+
+    ColumnLayout {
+        anchors.fill: parent
+        anchors.margins: sidebarPadding
+        
+        spacing: sidebarPadding
+
+        PrimaryTabBar { // Tab strip
+            id: tabBar
+            visible: root.tabButtonList.length > 1
+            tabButtonList: root.tabButtonList
+            externalTrackedTab: root.selectedTab
+            function onCurrentIndexChanged(currentIndex) {
+                root.selectedTab = currentIndex
+            }
+        }
+
+        SwipeView { // Content pages
+            id: swipeView
+            Layout.topMargin: 5
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            spacing: 10
+            
+            currentIndex: tabBar.externalTrackedTab
+            onCurrentIndexChanged: {
+                tabBar.enableIndicatorAnimation = true
+                root.selectedTab = currentIndex
+            }
+
+            clip: true
+            layer.enabled: true
+            layer.effect: OpacityMask {
+                maskSource: Rectangle {
+                    width: swipeView.width
+                    height: swipeView.height
+                    radius: Appearance.rounding.small
+                }
+            }
+
+            contentChildren: [
+                ...((root.aiChatEnabled || (!root.translatorEnabled && !root.animeEnabled)) ? [aiChat.createObject()] : []),
+                ...(root.translatorEnabled ? [translator.createObject()] : []),
+                ...(root.animeEnabled ? [anime.createObject()] : [])
+            ]
+        }
+
+        Component {
+            id: aiChat
+            AiChat {}
+        }
+        Component {
+            id: translator
+            Translator {}
+        }
+        Component {
+            id: anime
+            Anime {}
+        }
+        
+    }
+}