Rearrange for tidier structure (#2212)

2025-10-16 07:19:55 +08:00
parent 13065d7e5a
commit 8b493e091d
529 changed files with 165 additions and 138 deletions
@@ -0,0 +1,128 @@
+pragma Singleton
+
+import QtQuick
+import qs.modules.common
+import Quickshell
+import Quickshell.Io
+
+/**
+ * Simple hyprsunset service with automatic mode.
+ * In theory we don't need this because hyprsunset has a config file, but it somehow doesn't work.
+ * It should also be possible to control it via hyprctl, but it doesn't work consistently either so we're just killing and launching.
+ */
+Singleton {
+    id: root
+    property string from: Config.options?.light?.night?.from ?? "19:00" 
+    property string to: Config.options?.light?.night?.to ?? "06:30"
+    property bool automatic: Config.options?.light?.night?.automatic && (Config?.ready ?? true)
+    property int colorTemperature: Config.options?.light?.night?.colorTemperature ?? 5000
+    property bool shouldBeOn
+    property bool firstEvaluation: true
+    property bool active: false
+
+    property int fromHour: Number(from.split(":")[0])
+    property int fromMinute: Number(from.split(":")[1])
+    property int toHour: Number(to.split(":")[0])
+    property int toMinute: Number(to.split(":")[1])
+
+    property int clockHour: DateTime.clock.hours
+    property int clockMinute: DateTime.clock.minutes
+
+    property var manualActive
+    property int manualActiveHour
+    property int manualActiveMinute
+
+    onClockMinuteChanged: reEvaluate()
+    onAutomaticChanged: {
+        root.manualActive = undefined;
+        root.firstEvaluation = true;
+        reEvaluate();
+    }
+
+    function inBetween(t, from, to) {
+        if (from < to) {
+            return (t >= from && t <= to);
+        } else {
+            // Wrapped around midnight
+            return (t >= from || t <= to);
+        }
+    }
+
+    function reEvaluate() {
+        const t = clockHour * 60 + clockMinute;
+        const from = fromHour * 60 + fromMinute;
+        const to = toHour * 60 + toMinute;
+        const manualActive = manualActiveHour * 60 + manualActiveMinute;
+
+        if (root.manualActive !== undefined && (inBetween(from, manualActive, t) || inBetween(to, manualActive, t))) {
+            root.manualActive = undefined;
+        }
+        root.shouldBeOn = inBetween(t, from, to);
+        if (firstEvaluation) {
+            firstEvaluation = false;
+            root.ensureState();
+        }
+    }
+
+    onShouldBeOnChanged: ensureState()
+    function ensureState() {
+        // console.log("[Hyprsunset] Ensuring state:", root.shouldBeOn, "Automatic mode:", root.automatic);
+        if (!root.automatic || root.manualActive !== undefined)
+            return;
+        if (root.shouldBeOn) {
+            root.enable();
+        } else {
+            root.disable();
+        }
+    }
+
+    function load() { } // Dummy to force init
+
+    function enable() {
+        root.active = true;
+        // console.log("[Hyprsunset] Enabling");
+        Quickshell.execDetached(["bash", "-c", `pidof hyprsunset || hyprsunset --temperature ${root.colorTemperature}`]);
+    }
+
+    function disable() {
+        root.active = false;
+        // console.log("[Hyprsunset] Disabling");
+        Quickshell.execDetached(["bash", "-c", `pkill hyprsunset`]);
+    }
+
+    function fetchState() {
+        fetchProc.running = true;
+    }
+
+    Process {
+        id: fetchProc
+        running: true
+        command: ["bash", "-c", "hyprctl hyprsunset temperature"]
+        stdout: StdioCollector {
+            id: stateCollector
+            onStreamFinished: {
+                const output = stateCollector.text.trim();
+                if (output.length == 0 || output.startsWith("Couldn't"))
+                    root.active = false;
+                else
+                    root.active = (output != "6500"); // 6500 is the default when off
+                // console.log("[Hyprsunset] Fetched state:", output, "->", root.active);
+            }
+        }
+    }
+
+    function toggle() {
+        if (root.manualActive === undefined) {
+            root.manualActive = root.active;
+            root.manualActiveHour = root.clockHour;
+            root.manualActiveMinute = root.clockMinute;
+        }
+
+        root.manualActive = !root.manualActive;
+        if (root.manualActive) {
+            root.enable();
+        } else {
+            root.disable();
+        }
+    }
+}