{
  wayland.windowManager.hyprland.settings = {
    bindd =
      [
        # essential
        "SUPER, Return, Open Terminal, exec, uwsm app -- xdg-terminal-exec"
        "SUPER, Q, Kill active, killactive"

        # move focus
        "SUPER, J, Move focus down, movefocus, d"
        "SUPER, K, Move focus up, movefocus, u"
        "SUPER, H, Move focus left, movefocus, l"
        "SUPER, L, Move focus right, movefocus, r"

        # fullscreen
        "SUPER, F, Toggle Fullscreen, fullscreen, 0"
        "SUPER SHIFT, F, Toggle Maximized Fullscreen, fullscreen, 1"

        # apps
        "SUPER, W, Open browser, exec, uwsm app -- firefox" # FIXME: must be xdg-open

        # [Workspaces] Toggle between most recent workspaces
        "SUPER, Tab, Cycle workspaces, workspace, previous"
      ]
      ++ (
        # Generate binds for Super + [1-10] to switch workspaces
        # and Super + Shift + [1-10] to move window to workspace
        builtins.concatLists (builtins.genList (
            i: let
              ws = i + 1;
              key = toString (
                if ws == 10
                then 0
                else ws
              );
            in [
              "SUPER, ${key}, Switch to workspace ${toString ws}, workspace, ${toString ws}"
              "SUPER SHIFT, ${key}, Move window to workspace ${toString ws}, movetoworkspace, ${toString ws}"
            ]
          )
          10)
      );
  };
}