{
  description = "Sakamoto's NixOS Configuration";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs"; # `follows` ensure it follows nixpkgs versiona. Avoids breaking updates.
    darwin.url = "github:lnl7/nix-darwin";
    darwin.inputs.nixpkgs.follows = "nixpkgs";

    ags.url = "github:aylur/ags";
    ags.inputs.nixpkgs.follows = "nixpkgs";

    hyprland.url = "github:hyprwm/Hyprland";
    hyprland.inputs.nixpkgs.follows = "nixpkgs";

    unlisted-fonts.url = "git+https://git.sakamoto.dev/kenji/nix-fonts.git";
    unlisted-fonts.inputs.nixpkgs.follows = "nixpkgs";

    nixovim.url = "git+https://git.sakamoto.dev/kenji/nixovim.git";
    nixovim.inputs.nixpkgs.follows = "nixpkgs";

    matugen.url = "github:/InioX/Matugen";
    matugen.inputs.nixpkgs.follows = "nixpkgs";

    nix-gaming.url = "github:fufexan/nix-gaming";
    nix-gaming.inputs.nixpkgs.follows = "nixpkgs";

    sops-nix.url = "github:Mic92/sops-nix";
    sops-nix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = {
    self,
    nixpkgs,
    home-manager,
    darwin,
    ags,
    hyprland,
    unlisted-fonts,
    nixovim,
    ...
  } @ inputs: let
    config = import ./config.nix;
    lib = nixpkgs.lib;
    system = "x86_64-linux";
    # pkgs = nixpkgs.legacyPackages.${system}; # alternative, without overlays. Unused.
    args =
      {
        inherit inputs system;
      }
      // config;
  in {
    # nixosConfiguration for linux system
    nixosConfigurations = {
      desktop = lib.nixosSystem {
        inherit system;
        specialArgs = args;
        modules = [
          ./hosts/desktop/configuration.nix
        ];
      };
    };
    homeConfigurations = {
      desktop = home-manager.lib.homeManagerConfiguration {
        pkgs = import nixpkgs {
          inherit system;
          overlays = [
            # (final: prev: {
            #   ags_1 = prev.ags_1.overrideAttrs (old: {
            #     buildInputs = old.buildInputs ++ [pkgs.libdbusmenu-gtk3];
            #   });
            # })
          ];
        };
        extraSpecialArgs = args;
        modules = [./home/desktop.nix];
      };

      gaming = home-manager.lib.homeManagerConfiguration {
        pkgs = import nixpkgs {
          inherit system;
          overlays = [];
        };
        extraSpecialArgs = args;
        modules = [./home/gaming.nix];
      };
      headless = home-manager.lib.homeManagerConfiguration {
        pkgs = import nixpkgs {
          inherit system;
          overlays = [];
        };
        extraSpecialArgs = args;
        modules = [./home/headless.nix];
      };
    };
    # darwinConfiguration for macOS M series
    darwinConfigurations = {
      macos = darwin.lib.darwinSystem {
        system = "aarch64-darwin";
        specialArgs = args;
        modules = [
          ./hosts/macos/darwin.nix
          home-manager.darwinModules.home-manager
          {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.extraSpecialArgs = args;
          }
        ];
      };
    };
  };
}